dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
dnl ------------------
dnl This is the "--enable-pc-files" option, which is available if there is a
dnl pkg-config configuration on the local machine.
AC_DEFUN([CF_ENABLE_PC_FILES],[
AC_REQUIRE([CF_PKG_CONFIG])
AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])

if test "$PKG_CONFIG" != none ; then
	AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
	AC_ARG_ENABLE(pc-files,
		[  --enable-pc-files       generate and install .pc files for pkg-config],
		[enable_pc_files=$enableval],
		[enable_pc_files=no])
	AC_MSG_RESULT($enable_pc_files)
	if test "$enable_pc_files" != no
	then
		CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
	fi
else
	enable_pc_files=no
fi
])dnl
